" Vim syntax file
" Language:	cs324 bin2a output
" Maintainer:	Hans Fugal <hans@fugal.net>
" URL:		http://fugal.net/vim/cs324.vim
" Last Change:	$Date: 2002/08/26 18:49:13 $

" Edit ~/.vim/filetype.vim, and put the following lines in it:
"
" " cs324 bin2a syntax
" augroup filetypedetect
"   au! BufRead,BufNewFile *.cs324	setfiletype cs324
" augroup END
" Redirect the output of bin2a to a file and edit it. Give the file the
" extension cs324. Example: 
" bin2a field.dlx > field.cs324

" For version 5.x: Clear all syntax items
" For version 6.x: Quit when a syntax file was already loaded
if version < 600
  syntax clear
elseif exists("b:current_syntax")
  finish
endif

" The Matches
syn match number /\d\+/
syn match hexNumber "0[xX]\s*[0-9a-fA-F]\+"lc=2
syn match regname /\<[rf]\d\+/
syn match imm /#\d\+/ms=s+1
syn match pcline /^\s*[0-9a-fA-F]\+:/me=e-1
syn match nop /\<nop\>/
syn match delimiter /[:,]/
syn match specialchar /[+\-#]/
syn match label /\S\+  0[xX]/me=e-2
syn match EA /EA=/
syn match comment /<<.*>>/
syn match hexprefix /0[xX]/
" just for fun
syn match byu /`BYU!'/

" The regions
syn region chars matchgroup=delimiter start=/"/ end=/"/ skip=/..../
syn region bracketed matchgroup=delimiter start=/\[/ end=/\]/ contains=hexNumber,EA,number,hexprefix,byu
syn region parenthesized matchgroup=delimiter start=/(/ end=/)/ contains=regname,hexnumber,number,hexprefix


" The keywords
syn keyword asmKeyword lb lbu sb lh lhu sh lw sw lf ld sf sd movi2s movs2i movf movd movfp2i movi2fp add addi addu addui sub subi subu subui mult multu div divu and andi or ori xor xori lhi sll srl sra slli srli srai slt sgt sle sge seq sne slti sgti slei sgei seqi snei beqz bnez bfpt bfpf j jr jal jalr trap rfe addd addf subd subf multd multf divd divf cvtf2d cvtf2i cvtd2f cvtd2i cvti2f cvti2d ltg ltg gtd gtf led lef ged gef eqd eqf ned nef ltf

" Define the default highlighting.
" For version 5.7 and earlier: only when not done already
" For version 5.8 and later: only when an item doesn't have highlighting yet
if version >= 508 || !exists("did_asm_syntax_inits")
  if version < 508
    let did_asm_syntax_inits = 1
    command -nargs=+ HiLink hi link <args>
  else
    command -nargs=+ HiLink hi def link <args>
  endif

  " The default methods for highlighting.  Can be overridden later
    HiLink	nop		warningmsg
    HiLink	pcline		linenr
    HiLink	imm		number
    HiLink	regname		identifier
    HiLink	chars		normal
    HiLink	hexNumber	Number
    HiLink	hexprefix	type
    HiLink	EA		special
    HiLink	asmKeyword	statement

    " Specific color settings
    hi byu ctermfg=white ctermbg=blue guifg=white guibg=blue

  delcommand HiLink
endif

let b:current_syntax = "cs324"

" vim: ts=8